МАГ

#showtooltip Counterspell
/stopcasting
/cast Counterspell

Макрос прерывает любой ваш каст и тут же пускает Counterspell, что позволяет вам вовремя законртить противника без каких либо телодвижений или ожидания окончания вашего каста. Такой макрос должен иметь каждый уважающий себя маг.

---------------------------------------------------------
Но как быть с овцой? Каждый раз на решип перецеливаться на шипованного моба? А после шипа опеть искать ДД-цель? Долго, возможны ошибки. Надо что-то придумать удобное, что бы можно было шиповать и перешиповывать не меняя ДД-цели. Вот какой макрос я придумал для себя и он мне очень понравился:
Код
#showtooltip Polymorph
/clearfocus [target=focus,dead]
/clearfocus [target=focus,noexists]
/focus [target=target,exists,harm,nomodifier:shift]
/focus [target=mouseover,exists,harm,nomodifier:shift]
/cast [target=focus] Polymorph

В ВоВе помимо зацеливания можно ставить еще и фокус ( /focus ). Таким образом, вы можете направлять свои действия на 2 цели одновременно: зацеленную и зафокусенную. Что делает этот макрос:
- Если под курсором мыши есть враждебная цель, то на нее ставится фокус и она шипуется.
- Если под курсором мыши нету враждебной цели, то фокус ставится на выделенную враждебную цель и она шипуется.
- Если при активации макроса была зажата клавиша Shift, то шипуется цель, на которой в данный момент находится фокус, при этом не важно какая цель сейчас выбрана в цель или курсором мыши. Зашипована будет именно та, на которой ранее был поставлен фокус. Если ни одна цель не имеет фокуса, зашипована будет выбранная цель.

Т.е. если просто активировать макрос, он будет ставить фокус и шиповать выбранную цель или цель под курсором мыши (курсор мыши имеет приоритет перед зацеленной). Если активировать макрос зажав клавишу Shift, то каст полиморфа будет направлен на цель имеющую ваш фокус.

Например, начинается распул и вам выделили цель для шипования. Зацельте ее или наведите на нее курсор мыши, в нужный момент активируйте макрос и переходите к своим ДД-функциям. Когда понадобится решип (индикатор показывает завершение полиморфа или моб вышел из полиморфа раньше времени), просто зажмите Shift и активируйте макрос. При этом ваша ДД-цель не теряется

--------------------------------------------
#showtooltip Ice Lance
/cast [target=mouseover,nodead] Ice Lance

Макрос на каст айс ленса по цели под курсором. Очень удобно не меняя цели сбивать тотемы.
--------------------------------------------
/use Conjured Crystal Water
/use Conjured Cinnamon Roll

Пьём и едим одним нажатием.
---------------------------------------------
Отмена текущего каста и каст айсблока (без отмены гкд)

/cancelaura Ice block
/stopcasting
/cast Ice block
----------------------------------------------
Элементаль--> Фриз

/cast [nopet] Summon WAter Elemental
/Stopmacro [nopet]
/petpassive
/click PetActionButton5
/petattack

Очень удобный макрос. На одну кнопку сначала призывается элементаль, затем при нажатии еще раз кидается фриз.

ВОИН

#showtooltip Spell Reflection
/cast [nostance:1/2] Defensive Stance
/cast [stance:1/2] Spell Reflection
/stopcasting
/stopmacro [equipped:shields]
/equip Dragonstrike
/equip Shield of Impenetrable Darkness

Макрос для быстрого перехода в деф стойку и включения спел рефлекта. Последние 2 строки это экипировка (оружие+щит)
-----------------------------------------------
Battle Stance/Mocking Blow

/cast [stance:1] Mocking Blow; Battle Stance

---------------------------------------------
Target then Charge and Bloodrage

/targetenemy [noexists]
/assist [help]
/cast [exists,nohelp,nocombat] Charge
/cast [combat] Bloodrage
------------------------------------------------

Defensive Stance/Taunt

/cast [stance:2] Taunt; Defensive Stance
------------------------------------------------

Berserker Stance/Berserker Rage

/cast [stance:3] Berserker Rage; Berserker Stance
------------------------------------------------

Berserker Rage/Defense

/cast [stance:3] Berserker Rage
/stopcasting
/cast [stance:3] Defensive Stance; Berserker Stance
------------------------------------------------

Always Overpower

/cast [stance:1] Overpower; Battle Stance
------------------------------------------------

Shield Bash or Pummel

/cast [stance:1/2,noequipped:Shields] Berserker Stance; [stance:1/2,equipped:Shields] Shield Bash; [stance:3] Pummel
------------------------------------------------

Charge/Defense

/cast [stance:1,nocombat] Charge
/stopcasting
/cast [stance:1] Defensive Stance; Battle Stance
------------------------------------------------

Intercept/Defense

/cast [stance:3] Intercept
/stopcasting
/cast [stance:3] Defensive Stance; Berserker Stance
------------------------------------------------

Intercept/Hamstring

/cast [stance:3] Intercept; Berserker Stance
/stopcasting
/cast [stance:3] Hamstring
------------------------------------------------

Charge/Intercept

/cast [nocombat,stance:1] Charge; [combat,nostance:3] Berserker Stance; [nocombat,nostance:1] Battle Stance; [combat,stance:3] Intercept
------------------------------------------------

Intervene

/cast [nostance: 2] Defensive Stance; [help] Intervene; [target=targettarget, help] Intervene
------------------------------------------------

Bloodrage & Berserker Rage

/cast Bloodrage
/stopcasting
/cast Berserker Rage
------------------------------------------------

All in one charge если не хотите быть в дефе, то удалите две последние строчки

/cast [stance:1/2,combat] Berserker Stance
/stopcasting
/cast [stance:3,combat] Intercept
/stopcasting
/cast [stance:2/3,nocombat] Battle Stance
/stopcasting
/cast [stance:1,nocombat] Charge
/stopcasting
/cast [equipped:Shields] Defensive Stance
/stopcasting
------------------------------------------------

Sunder & Shield Block

/cast [stance:2] Sunder Armor
/stopcasting
/cast Shield Block
------------------------------------------------
Пока это все. В дальнейшем постараюсь выложить макросы для других классов.

Добавлено (01 Сентябрь 2008, 13:18)
---------------------------------------------
ШАМАН

/cast [target=mouseover] Cure Poison;

Этот макрос будет снимать яд по таргету мышки. Аналогичные макросы можно написать на любой спелл путём замены в макросе названия спелла.

#showtooltip Bloodlust
/cast Bloodlust(Rank 1)
/p макс дпс!!!

Обычный блуд ласт, только с оповещеним для группы

/castsequence [target=player, combat] reset=120 War Stomp(Racial), Lesser Healing Wave

для тауренов - топаем, лечимся. Макрос нужно нажимать 2 раза - первое нажатие топнуть, второе лечить себя, макрос реботает только в бою (чтоб экономить)

/castsequence тотем1, тотем2, тотем3, тотем4

Если вместо "тотем1, тотем2 и тд" написать имена тотемов, то при нажатии на макрос бедут появляться тотемы поочереди (внимание - запускается кулдаун, поэтому нажимать нужно не чаще 1 раза в секунду)

/cast [target=player, modifier:Shift] Cure Poison;
/use [target=player, modifier:alt] 13;
/cast [help, nomodifier] Lesser Healing Wave;
/cast [nomodifier, target=mouseover, harm]Purge; [nomodifier, harm]Purge;

- Shift+<macro> - Снимаем с себя яд
- alt+<macro> - Юзаем тринкет в 13-м слоте инвентаря
- Если на таргете френд - Лечим его Lesser Healing Wave
- Если враг: на таргете И\ИЛИ просто под курсором мыши - Пуржим

#showtooltip Lesser Healing Wave
/cast [help] Lesser Healing Wave
/stopmacro [help]
/cast [target=mouseover,help] Lesser Healing Wave
/stopmacro [target=mouseover,help]
/cast [target=player] Lesser Healing Wave